Mở lại bản vẽ AutoCAD cuối cùng | Open last closed drawing in AutoCAD | AutoLisp Reviewer

Ứng dụng được phát triển bởi đội ngũ AutoLISP Thật là đơn giản

    

Thông tin thêm: 👉👉👉

Giới thiệu

Đoạn code dùng để mở bản vẽ cuối cùng trước khi đóng AutoCAD:

• Các bác biết khi mở Chrome, nếu vô tình hoặc cố ý đóng 1 tab, thì chỉ cần Ctrl+T là sẽ mở lại tab vừa đóng.

• Có thể áp dụng lên AutoCAD bằng Reactor. Mỗi khi đóng bản vẽ => Lưu lại đường dẫn bản vẽ được đóng.

• Sử dụng lệnh Openlastdwg để mở bản vẽ được đóng gần nhất.

• Có thể tối ưu thêm bằng cách gán lệnh tắt Ctrl+T => chạy lệnh Openlastdwg

• Có thể áp dụng khi khởi động AutoCAD

Cài đặt thủ công

1 Thêm tệp tin Openlastdwg.lsp

(Copy nội dung sau)

Code:

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun SaveCurrentDwgName (args reac / filename )
	(if (and (setq filename (strcat (getvar "dwgprefix") (getvar "dwgname")))
			(setq filename (findfile filename))
			)
		(setenv "LH-LastDWG" filename)
	)
)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun openlastdwg ( / file filename)
	(command nil) ;;cancel any active command
	(if (and (setq filename (getenv "LH-LastDWG")) (findfile filename))
		(progn
			(if (setq file (vla-open (vla-get-Documents (vlax-get-acad-object)) filename :vlax-false))
				(vla-activate file)
			)
		);progn then
		(progn (princ "\nsample-lsp-open error- File not found: ")(princ filename))
	);if
	(command nil) ;;cancel any active command
	(princ)
);defun sample-lsp-open
(defun c:Openlastdwg ()
	(openlastdwg)
	(princ)
)
(defun Create_Close_Reactor()
	(vl-load-com)
	(if (not close:reactor)
		(setq close:reactor
			(vlr-editor-reactor nil
			'((:vlr-beginClose . SaveCurrentDwgName)))
		)
	); end if
	(princ)
); end of Create_Close_Reactor
(Create_Close_Reactor)

Tải Setup.exe

Ngoài ra, bạn có thể tải ứng dụng cài đặt để tối ưu hóa toàn bộ công việc trên trong nhóm

http://newz.lisp.vn

Link tải (AutoCAD > 2015)

📥 https://www.mediafire.com/

Hướng dẫn cài đặt

Code:

;;;;;;;;;; www.lisp.vn ;;;;;;;;;;
[Setup] Xin vui lòng tải bộ cài để cài đặt. Hướng dẫn cài đặt:
👉 Tải file và Giải nén (rar 🗜️)
👉 Đóng AutoCAD, Click đúp Setup[.exe], chọn Extract (giải nén) => OK 🧰
👉 Mở AutoCAD, chọn Always load (Nếu có)
👉 Gõ lệnh tương ứng với ứng dụng [OLD] hoặc nhấn tổ hợp phím Ctrl+T
👉 Chạy thử 🎮 các chức năng của chương trình như Video hướng dẫn

    

---------------------------------------------------------------------------------------------

Ứng dụng được phát triển bởi đội ngũ AutoLISP Thật là đơn giản - Tác giả ứng dụng in D2P

    

Mọi thông tin xin liên hệ Fanpage AutoLISP Thật là đơn giản!

Cảm ơn bạn đã theo dõi!